; cornelia's reading/night light with auto-off
; copyright (c) 2008 Alexander Zangerl <az@snafu.priv.at>
;
; This program is free software; you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation (version 2 of the License).
;
; $Id: nightlight.asm,v 1.3 2008/02/18 12:29:23 az Exp $

processor p12f629
#include "p12f629.inc"

	RADIX hex

	__CONFIG _INTRC_OSC_NOCLKOUT & _BODEN_OFF & _MCLRE_ON & _WDT_OFF & _CP_OFF

LBIT	equ	0	;gp0 is light control

	cblock 0x20
	scritch			; tempvar
	scratch			; tempvar for delay routines
	foo			; tempvar
	endc

	org 0			; power-on or reset
	goto main
	org 0x4			; interrupt table
	retfie			; no ints used

main:	; setup output
	movlw	7
	movwf	CMCON		; comparator off!
	bsf	STATUS,RP0	; bank1
	movlw	0xff & ~(1<<LBIT)
	movwf	TRISIO		; those bits output
	bcf	OPTION_REG,INTEDG ; interrupt on gp2 on by default!

	; power on reset (not_por is 0) or reset during op or sleep? 
	btfsc	PCON,NOT_POR
	goto	toggle_state	; as in reset-during-op
	bsf	PCON,NOT_POR	; remember that we're up for future mclrs
	bcf	STATUS,RP0	; back in bank0
	clrf	GPIO
	bsf	GPIO,LBIT	; light on please!
	goto	wait		; and wait until done!

toggle_state:		
	bcf	STATUS,RP0	; bank0
	movlw	1<<LBIT
	xorwf	GPIO,F		; invert the state

	btfss	GPIO,LBIT	; current light state = off? skip if on
	sleep			; we're done

wait:	; otherwise delay for ~15min
	; 18.0906min precisely,
	; i'm too lazy to adjust that down
	clrf	foo
more:	clrw
	call	delayXms	; 256ms
	call	delayXms	;
	call	delayXms	; 
	call	delayXms
	; 1s
	call	delayXms	; 256ms
	call	delayXms	; 
	call	delayXms	; 
	call	delayXms
	call	delayXms	; 256ms
	call	delayXms	; 
	call	delayXms	; 
	call	delayXms
	call	delayXms	; 256ms
	call	delayXms	; 
	call	delayXms	; 
	call	delayXms
	; 4.096s
	incf	foo,F
	btfss	STATUS,Z	; skips if foo is zero
	goto	more
	
	; and then lights off and sleep
	bcf	GPIO,LBIT
	sleep
	
	
#include "delay.inc"	
	org	0x2100		; eeprom
version	equ $-0x2100	
	de	"$Id: nightlight.asm,v 1.3 2008/02/18 12:29:23 az Exp $"
end